Добавить форум Lasers.fonarevka.ru в Избранное ×
LASERS.FONAREVKA.RU - Всё о лазерах и лазерной технике  

Вернуться   Форум Lasers.fonarevka.ru > Лаборатория > Питание лазеров > Драйверы для Фиолетовых ЛД > В разработке
Забыли пароль? Регистрация
Темы с вашим участием Новые сообщения Сообщения за день

  • Бесплатные розыгрыши призов
  • Для гостей форума
  • Пожертвования (Donate)
На форуме ежемесячно проходят бесплатные розыгрыши призов для зарегистрированных и активно общающихся форумчан. Вы можете выиграть не только различные лазерные указки и другое лазерное оборудование, но и фонарики, зарядные устройства, аккумуляторы и другие аксессуары известных брендов, а также фонари и компоненты от известных кастомщиков и мелкосерийных производителей. Также разыгрываются и другие призы, такие как мультитулы, ножи, рюкзаки и другое снаряжение. Все проходящие розыгрыши призов являются действительно абсолютно бесплатными для самих участников, т.к. все расходы берут на себя организаторы (т.е. владельцы данного форума) и сами спонсоры, которые предоставляют тот или иной приз для наших розыгрышей призов. Форумчане не несут никаких имущественных рисков, связанных с участием в данных розыгрышах (т.е. вы ничего не оплачиваете и ничем не рискуете). Вам достаточно нажать кнопку "Принять участие" и ждать результата!

На данный момент проходит 1 розыгрыш призов.

1. Зарядное устройство XTAR XP4 Panzer + 2 аккумулятора Panasonic NCR18650B 3400 мАч

Рекомендуем Вам подписаться на тему (оптимальнее с уведомлением на ваш E-mail), где публикуется информация о новых розыгрышах призов.
Подробная информация по ссылке
Искренне рады видеть Вас на нашем независимом проекте о лазерах и лазерной технике!

Что Вам даст регистрация на нашем проекте:


- Возможность участия во всевозможных акциях, конкурсах и лотереях постоянно проходящих на форуме
- Возможность пользоваться скидками и бонусами, которые предоставляют различные популярные магазины специально для наших форумчан
- Возможность побывать в роли тестеров новейших разработок в области лазерной техники и их комплектующих
- Возможность неограниченного доступа к закрытой технической информации и некоторым интересным разделам форума

и много других приятных привилегий

Искренне надеемся, что Вам у нас понравится!
Если вы хотите финансово поддержать работу проекта LASERS.FONAREVKA.RU, будем искренне благодарны!
Даже самая малая сумма поможет дальнейшему развитию и прогрессу нашего с вами уже общего проекта.


Ответ
Просмотров в теме 7370   Ответов в теме 22   Подписчиков на тему 3   Добавили в закладки 0
Опции темы
Старый 04.04.2011, 12:24   1
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию Indigo 3.0 (на ATtiny25)

Всем привет . Приспичило меня собрать десяток драйверов к 12х, человек давно уже ждёт. Облазил сайты изготовителей компонентов и снова не нашел подходящий чип. Решил поискать среди контроллеров, и ничего лучше ZXSC400 не нашел. Нарисовал схему, развёл печатку, собрал - глючит. Изменил схему, переразвёл печатку, собрал - всё равно глючит. Дело в том что китайцы экономили на всём, даже слип реализовали через "пятую точку". Сам преобразователь то завёлся, и выдал нужный ток с приемлемым КПД, но стоило уменьшить напряжение до порога срабатывания супервизора (а без него вообще нельзя - схему гарантировано клинит и она сгорает), как контроллер засыпая зачем-то открывал ключ и уже ничего не соображал. При включении тоже самое. Некоторое время контроллер дуплится, при этом зачем-то открывая ключ и закорачивая питание. Из-за этого супервизор срабатывал и схему начинало колбасить. Не помог даже мощный фильтр на питании супервизора - задержки в единицы миллисекунд. К тому же режим работы такого контроллера не оптимальный, как следствие высокий уровень пульсаций и большой реактивный ток дросселя (ну и снижение КПД из-за этого). Ещё для нормальной работы он требует много обвеса (супервизор, защита от перенапряжения, драйвер для раскачки ключа и т.п.), да и частота хромает. В общем не советую вам с ними связывается, не знаю как народ их юзает без проблем. Всегда от них тошнило, но в этот раз я ещё и убедился в своих предположениях. Кстати, этому драйверу я дал ласковое название "Bluvatron" ...

Но из ситуации надо как-то выкручиваться. Откопал я у себя жменю 45-х тинек, припасённых для RGB индикаторов, и решил собрать дрова на них. К счастью почти все детали подошли от этой злосчастной схемы. К моему удивлению схема получилась куда проще, и даже габариты такие же:
Нажмите на изображение для увеличения
Название: ATtiny25.PNG
Просмотров: 946
Размер:	36.7 Кб
ID:	4265
Долго мучал программу. За основу взял уже хоть как-то работающий инвертирующий драйвер для 808nm ЛД, вырезал больше половины (там механизм сложнее) и кое что подправил:
Код:
; Преобразователь на ATtiny45. Тактовая 8МГц, ШИМ 250кГц.


	.INCLUDE "tn45def.inc"

;вектора прерываний:

	rjmp	RESET
	reti
	reti
	reti
	rjmp	Over1

	sbi	GPIOR1, 2		;Установить флаг Over0
	reti
	reti
	rjmp	ADCOMP
	reti

	reti
	reti
	reti
	reti
	reti


;Конфигурация:

RESET:	Ldi	R16, HIGH(RAMEND-6)	;инициализация стека
	out	SPH, R16
	Ldi	R16, LOW(RAMEND-6)
	out	SPL, R16

	ldi	R16, 0b00100001		;PB5 и PB0 - подтягивание
	out	PORTB, R16

	ldi	R16, 0b00000010		;PB1 - выход
	out	DDRB, R16

	ldi	R16, 0b10000000		;выключение аналогового компаратора
	out	ACSR, R16

	ldi	R16, 0b00011100		;выключение цифрового входа на PB2, PB3 и PB4
	out	DIDR0, R20

	ldi	R16, 0b00101000		;Sleep, режим ADC Noise Reduction
	out	MCUCR, R16

	ldi	R16, 0b10000101		;Измерение offset
	out	ADMUX, R16

	ldi	R16, 0b11001110		;Включить АЦП, запуск, ADCOMP, тактовая clk/64
	sei
	out	ADCSRA, R16
	sleep
	cli

	ldi	R16, 0b00000010		;Включить PLL
	out	PLLCSR, R16

	clr	R0
	clr	R3
	clr	R4
	clr	R5
	clr	R24
	clr	R25

	ldi	R17, 0x08		;Стартовый ток 0,03А
	ldi	R16, 0xA6
	mov	R6, R16
	mov	R7, R17

	ldi	R17, 0x81		;Заданный ток 0,45А
	ldi	R16, 0xC2
	mov	R8, R16
	mov	R9, R17

	ldi	R16, 0b00000110		;Включить Over1 и Over0
	out	TIMSK, R16

	ldi	R16, 0b00000100		;Запуск таймера0 (Clk/256)
	out	TCCR0B, R16

	ldi	R16, 0b00100000		;Sleep, режим Idle
	out	MCUCR, R16

	sei				;Разрешение прерываний


;============================================================================================
;Основной цикл:

main:	sbic	GPIOR1, 0		;Обновить ШИМ, если флаг готовности данных установлен
	rjmp	update
	Sleep
	rjmp	main


;Расчёт длительности импульса, сердце программы:

	;Глобальные переменные:

	;RAMEND-1	- Температура
	;RAMEND-3	- Выходное напряжение
	;RAMEND-5	- Выходной ток
	;R7:R6		- Сглаженный ток
	;R9:R8		- Заданный ток

	;1мкс		= 16384


update:	cbi	GPIOR1, 0		;Очистить флаг готовности исходных данных

	ldi	ZH, HIGH(RAMEND-5)	;Загрузить исходные данные в буфер
	ldi	ZL, LOW(RAMEND-5)
	ld	R10, Z+			;Iout
	ld	R11, Z+
	ld	R12, Z+			;Vout
	ld	R13, Z+
	ld	R14, Z+			;Temp
	ld	R15, Z+

	sbi	ADCSRA, 6		;Запуск измерения температуры

	ldi	R17, 0xF7		;Порог выходного напряжения (триггер 6V5)
	ldi	R16, 0xBF
	cp	R16, R12
	cpc	R17, R13
	brcc	vok
	clr	R24
	clr	R25
	rjmp	tok

vok:	ldi	R17, 0x88		;Порог тока (триггер 0,4725A)
	ldi	R16, 0x3F
	cp	R16, R10
	cpc	R17, R11
	brcc	iok
	clr	R24
	clr	R25
	rjmp	tok

iok:	sbis	GPIOR1, 2		;Сгладить изменение тока, если флаг установлен
	rjmp	outp


;Плавный пуск (122Hz):

	cbi	GPIOR1, 2		;Очистить флаг сглаживания тока
	mov	R16, R8
	mov	R17, R9

	mov	R18, R6			;Скорость изменения
	mov	R19, R7
	lsr	R19			;damped / 32
	ror	R18
	lsr	R19
	ror	R18
	lsr	R19
	ror	R18
	lsr	R19
	ror	R18
	lsr	R19
	ror	R18

	ldi	R21, 0x00
	ldi	R20, 0x64		;Минимальные ступеньки
	cp	R18, R20
	cpc	R19, R21
	brcc	dampok
	mov	R18, R20
	mov	R19, R21

dampok:	sub	R16, R6			;damped=damped+k
	sbc	R17, R7
	cp	R16, R18
	cpc	R17, R19
	brcc	damp1	
	mov	R18, R16
	mov	R19, R17
	in	R16, TIMSK
	andi	R16, 0b11111101		;выключить Over0
	out	TIMSK, R16
	out	TCCR0B, R0		;Остановить таймер0
damp1:	add	R6, R18
	adc	R7, R19


;Расчёт длительности импульса:

;Уменьшение длительности импульса по максимальной положительной ошибке:

outp:	mov	R16, R10		;Токовый порог (переменная)
	mov	R17, R11
	sub	R16, R6
	sbc	R17, R7

	breq	ziout
	brcc	piout
	clr	R16
	clr	R17
	rjmp	ziout

piout:

	cp	R16, R0
	cpc	R17, R0
	brne	ziout
	inc	R16


ziout:	mov	R18, R12
	mov	R19, R13
	subi	R18, 0x1F		;Порог выходного напряжения (6V3)
	sbci	R19, 0xF0
	brcc	pvout
	clr	R18
	clr	R19


pvout:	mov	R20, R14
	mov	R21, R15
	subi	R20, 0x40		;Температурный порог (60 градусов)
	sbci	R21, 0x57
	breq	ztmp
	brcc	ptmp
	clr	R20
	clr	R21
	rjmp	ztmp

ptmp:	lsr	R21			;/64
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20

	cp	R20, R0
	cpc	R21, R0
	brne	ztmp
	inc	R20


ztmp:	cp	R16, R18		;Вычисление максимальной ошибки
	cpc	R17, R19
	brcc	more1
	mov	R16, R18
	mov	R17, R19
more1:	cp	R16, R20
	cpc	R17, R21
	brcc	more2
	mov	R16, R20
	mov	R17, R21

more2:	cp	R16, R0
	cpc	R17, R0
	breq	zero

	sub	R24, R16
	sbc	R25, R17
	brcc	equt0
	clr	R24
	clr	R25
equt0:	rjmp	equt


;Увеличение длительности импульса по минимальной отрицательной ошибке:

zero:	mov	R16, R6			;Токовый порог (переменная)
	mov	R17, R7
	sub	R16, R10
	sbc	R17, R11


ziout2:	ldi	R19, 0xF0		;Порог выходного напряжения (6V3)
	ldi	R18, 0x1F
	sub	R18, R12
	sbc	R19, R13


zvout2:	ldi	R21, 0x57		;Температурный порог (60 градусов)
	ldi	R20, 0x40
	sub	R20, R14
	sbc	R21, R15
	breq	ztmp2

	lsr	R21			;/64
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20
	lsr	R21
	ror	R20

	cp	R20, R0
	cpc	R21, R0
	brne	ztmp2
	inc	R20


ztmp2:	cp	R18, R16		;Вычисление минимальной ошибки
	cpc	R19, R17
	brcc	more12
	mov	R16, R18
	mov	R17, R19
more12:	cp	R20, R16
	cpc	R21, R17
	brcc	more22
	mov	R16, R20
	mov	R17, R21

more22:	cp	R16, R0
	cpc	R17, R0
	breq	equt

	add	R24, R16
	adc	R25, R17
	brcc	equt
	ser	R24
	ser	R25


;Загрузка расчётного значения в ШИМ:

equt:	ldi	R17, 0xAA		;Максимальная длительность импульса (66%)
	ldi	R16, 0xAA
	cp	R16, R24
	cpc	R17, R25
	brcc	tok
	mov	R24, R16
	mov	R25, R17

tok:	mov	R16, R25
	inc	R16
	brne	okm
	ser	R16
okm:	cli
	mov	R3, R16
	mov	R4, R24
	mov	R5, R25
	sei

	in	R16, PLLCSR		;Проверка стабильности PLL
	sbrc	R16, 0
	rjmp	pllok
	out	TCCR1, R0		;Остановить ШИМ
	rjmp	main

pllok:	ldi	R16, 0b00000111		;Подключение PLL к таймеру
	out	PLLCSR, R16
	ldi	R16, 0b01100001		;Запуск таймера1 (pck/1), установка ШИМ на PB1
	out	TCCR1, R16
	rjmp	main
;============================================================================================




;Прерывание ШИМ (расширение разрядности):

	;R1		- Counter
	;R2		- SREG
	;R3		- R3=R5+1
	;R5:R4		- Длительность импульса

Over1:	in	R2, SREG
	inc	R1
	cp	R1, R4
	brcc	lowm
	out	OCR1A, R3
	out	SREG, R2
	reti

lowm:	out	OCR1A, R5
	out	SREG, R2
	reti




;Прерывание АЦП:

ADCOMP:	sei
	push	R16
	in	R16, SREG
	push	R16
	push	R17
	push	R18
	push	R19
	push	R20
	push	R21
	push	R22
	push	R23
	push	ZL
	push	ZH

	in	R16, ADMUX
	cpi	R16, 0b10000001
	breq	next1			;Перейти, если АЦП мерял Vout
	cpi	R16, 0b10000111
	breq	next2			;Перейти, если АЦП мерял Iout
	cpi	R16, 0b10000101
	breq	offset			;Перейти, если АЦП мерял offset


;Температура

	in	R16, ADCL		;Записать данные АЦП в буфер
	in	R17, ADCH

	ldi	R18, 0b10000001		;Запуск измерения Vout
	out	ADMUX, R18
	sbi	ADCSRA, 6

	ldi	ZH, HIGH(RAMEND-1)	;Сглаживание
	ldi	ZL, LOW(RAMEND-1)
	ld	R18, Z+
	ld	R19, Z+
	rcall	damper
	st	-Z, R19
	st	-Z, R18

	rjmp	adout


;Выходное напряжение

next1:	in	R16, ADCL		;Записать данные АЦП в буфер
	in	R17, ADCH

	ldi	R18, 0b10000111		;Запуск измерения Iout
	out	ADMUX, R18
	sbi	ADCSRA, 6

	ldi	ZH, HIGH(RAMEND-3)	;Сглаживание
	ldi	ZL, LOW(RAMEND-3)
	ld	R18, Z+
	ld	R19, Z+
	rcall	damper
	st	-Z, R19
	st	-Z, R18

	rjmp	adout


;Ток

next2:	sbic	GPIOR1, 1		;Выкинуть семпл, если он первый
	rjmp	Igood
	sbi	GPIOR1, 1
	sbi	ADCSRA, 6
	rjmp	adout

Igood:	cbi	GPIOR1, 1
	in	R16, ADCL		;Записать данные АЦП в буфер
	in	R17, ADCH
	sub	R16, R28
	sbc	R17, R29

	ldi	R18, 0b10001111		;Измерение температуры
	out	ADMUX, R18

	ldi	ZH, HIGH(RAMEND-5)	;Сглаживание
	ldi	ZL, LOW(RAMEND-5)
	ld	R18, Z+
	ld	R19, Z+
	rcall	damper
	st	-Z, R19
	st	-Z, R18

	sbi	GPIOR1, 0		;Установить флаг готовности исходных данных

adout:	pop	ZH
	pop	ZL
	pop	R23
	pop	R22
	pop	R21
	pop	R20
	pop	R19
	pop	R18
	pop	R17
	pop	R16
	out	SREG, R16
	pop	R16
	reti


offset:	sbic	GPIOR1, 1		;Выкинуть семпл, если он первый
	rjmp	offg
	sbi	GPIOR1, 1
	sbi	ADCSRA, 6
	rjmp	adout

offg:	cbi	GPIOR1, 1
	in	R28, ADCL		;Записать данные АЦП в буфер
	in	R29, ADCH

	ldi	R18, 0b10001111		;Запуск измерения температуры
	out	ADMUX, R18
	sbi	ADCSRA, 6
	rjmp	adout


;Сглаживание шума АЦП:

damper:	ldi	R21, 0x01		;Порог (6LSB)
	ldi	R20, 0x80

	lsl	R16			;АЦП x 64
	rol	R17
	lsl	R16
	rol	R17
	lsl	R16
	rol	R17
	lsl	R16
	rol	R17
	lsl	R16
	rol	R17
	lsl	R16
	rol	R17

	cp	R16, R18
	cpc	R17, R19
	breq	outd			;Вернутся, если равно
	brcs	lessd			;Перейти если main < damped

	mov	R22, R16
	mov	R23, R17
	sub	R22, R18
	sbc	R23, R19
	cp	R22, R20
	cpc	R23, R21
	brcc	overd			;При зашкаливании за порог пропустить без фильтрации

	ldi	R21, 0x00		;Уровень фильтрации вверх
	ldi	R20, 0x01

	add	R18, R20
	adc	R19, R21
outd:	ret

lessd:	mov	R22, R18
	mov	R23, R19
	sub	R22, R16
	sbc	R23, R17
	cp	R22, R20
	cpc	R23, R21
	brcc	overd			;При зашкаливании за порог пропустить без фильтрации

	ldi	R21, 0x00		;Уровень фильтрации вниз
	ldi	R20, 0x01

	sub	R18, R20
	sbc	R19, R21
	ret

overd:	mov	R18, R16
	mov	R19, R17
	ret

Программа весит меньше килобайта, так что её можно подправить и засунуть в 25-ю тиньку. Ещё можно спокойно поднять частоту ШИМ до 500кГц без последствий (скорость работы программы позволяет). Но этими я займусь позже, когда отправлю человеку это дело и найду свободное время для дальнейшего полирования девайса.

Сейчас в ней реализован плавный пуск (причём хитрый), ШИМ 16-ти битный и работает на частоте 250кГц (500кГц даст 14 бит, чего тоже с головой), защита от перенапряжения, триггеры, которые сбрасывают тягу до нуля, если ОС не успевает выровнять выброс на выходе, защита от перегрева (где-то на 60...65 градусов), ограничение максимальной длительности импульса в 66% (на всякий случай, на практике больше и не понадобится), ну и всё вроде...

Использовать МК в преобразователях для ЛД я не хотел до последнего момента. Они слишком медленно реагируют на изменения напряжения питания. Без дополнительных примочек я получил выбросы в 300мА на токе в 0,5A, если резко поднять напряжение питания на 1V (правда средний ток при таких пульсациях был всего 250мА)! Дребезг не страшен, т.к. ОС не успевает перерегулировать, но если вы запитаете драйвер, подождёте пока он вырулит нужный ток и резко поднимите напряжение - получите небольшой выброс, где-то в 50...100мА (если верить осциллографу). Дальше срабатывает триггер и преобразователь резко сбрасывает тягу, после чего медленная ОС выруливает нужный ток. С напряжением тоже самое, но конденсатор способен выдержать кратковременное перенапряжение, ему это не грозит. На схеме керамика, она даст пульсации в несколько раз ниже чем танталы, при почти одинаковой стоимости и габаритах (уже проверил). У меня же юзаются танталы, пульсации на выходе 50...75mV. Все замеры проводились при напряжении питания 2,7...4,2V, и токе нагрузки 450мА. Ещё на схеме резистор на 100 миллиОм, у меня же 50 (ошибка больше, но других у меня нет). Ток гуляет от напряжения питания в пределах плюс минус 10мА, с 100мОм резистором будет меньше. Максимальный расчётный ток - 0,5A (при напряжении на выходе около 6V). КПД получилось 85...90%. При этом драйвер спокойно ест за ампер, учитывайте это. Скорее всего его можно разогнать до 750мА, особенно если поднять частоту.

Вот печатка и схема в редактируемых форматах: Повышалка на ATtiny25.rar
Сюда же закинул spl7, asm и hex. Попытался сделать фотографии готового девайса, аккумы в конец убитые, даже на кадр не хватает ...

Имейте ввиду, что это только грубая, первая бета-версия, и в ней ещё есть что полировать. Так что посматривайте в конец темы, буду выкладывать более свежие решения...

Схема прошла тестирование на эквивалентной нагрузке (цепочка диодов с резистором), резистивной и максимально тяжелой (цепочка диодов), на источнике питания с высоким выходным сопротивлением, низким, и промодулированным меандром 1V, с частотой 10Гц (всплески ловил). Переходная характеристика с выбросом вверх и перерегулированием вниз, но без малейшего намёка на звон. Это очень актуальные проблемы в преобразователях на МК, особенно если ими нужно питать нежные ЛД.
Ещё я рискнул подключить синий ЛД - светит на все 450мА, плавный пуск отрабатывается хорошо. Подключил бы 12х фиолет, но у меня его нет ...

P.S. Пробовал реализовать супервизор, который бы плавно выключал схему, или ограничивал бы ток по минимальному напряжению питания. Решил мерить напряжение по идее Рязанца, без внешнего обвеса. Шумит просто звиздец, ещё и требует после мультиплексирования выбрасывать первый семпл. В шумодаве пришлось ставить порог в 30LSB, и то проскакивали импульсы по-более! Для измерения остальных параметров хватало и 3LSB. Для индикатора, в принципе, сгодится. Там скорость не требуется, можно агрессивный фильтр поставить. Но для преобразователя, быстродействие которого висит только на АЦП - лишние два семпла ощутимо увеличивают тормоза, а результат сомнителен. В общем выключение происходит как в обычном драйвере - цикличными миганиями - МК перезагружается при напряжениях ниже 2,7V своими аппаратными средствами (не забудьте прошить фьюзы!). Т.к. в регистрах информация сохраняется даже после выключения питания, а МК может узнать что привело к его перезагрузке, можно реализовать переключение режимов прерыванием питания...

[Исправлено: Hobbi TV, 04.04.2011 в 17:13].
INFERION вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 16:29   2
nevil
Лазеростроитель
 
Аватар для nevil
 
Регистрация: 17.12.2010
Последняя активность: 12.11.2015 02:01
Адрес: Электросталь
Сообщений: 1072
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
По умолчанию

ждем заводских плат?)
хотя для начала надо заказать партию лд)
__________________
Лучшая работа - это высокооплачиваемое хобби!

http://www.youtube.com/user/nevil91
nevil вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 17:22   3
Hobbi TV
Старший модератор
 
Аватар для Hobbi TV
 
Регистрация: 14.02.2010
Последняя активность: 18.11.2015 19:18
Адрес: Санкт-Петербург
Сообщений: 13534
Сказал(а) спасибо: 6
Поблагодарили 35 раз(а) в 30 сообщениях
По умолчанию

Поздравляю, это явно драйвер следующего поколения!

Добавлено через 2 минуты
Цитата:
Посмотреть сообщение Сообщение от nevil :
для начала надо заказать партию лд
Что-то типа этого...
__________________
моб.: +7-931-336-3737
e-mail: shop@hobbi.tv
Hobbi TV вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 17:24   4
Vik
Научный сотрудник
 
Аватар для Vik
 
Регистрация: 24.06.2010
Последняя активность: 10.01.2019 09:57
Адрес: Новокузнецк
Сообщений: 1590
Сказал(а) спасибо: 1
Поблагодарили 0 раз(а) в 0 сообщениях
По умолчанию

Странные весьма эти фиолеты 12х... Я досихпор не понял что произошло с моим, да и у многих умерли при странных обстоятельствах... У меня есть такая мысль что на LPF просто многие не отписываются о юзании 12х фиолетов, молчат... Скрывая что их поумерало туева хуча.
__________________

ICQ#: 496612593
Vik вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 17:26   5
nevil
Лазеростроитель
 
Аватар для nevil
 
Регистрация: 17.12.2010
Последняя активность: 12.11.2015 02:01
Адрес: Электросталь
Сообщений: 1072
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
По умолчанию

Hobbi TV как читаеш такое, теперь инет на на весь евросоюз, интересно с лпф будут покупать дрова?
nevil вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 17:26   6
Ryazanec
Переводчик
 
Регистрация: 04.05.2010
Последняя активность: 13.03.2019 20:23
Адрес: Рязань
Сообщений: 2389
Сказал(а) спасибо: 6
Поблагодарили 7 раз(а) в 6 сообщениях
По умолчанию

А я так в индикаторе и мерил, так как в момент включения приходится выбрасывать несколько выборок. Для индикатора без разницы - там от этой тормзнутости не сгорит ничего (да и погрешность не так страшна), а в драйвере только внешний делитель - нужно быстродействие.
Ryazanec вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 17:27   7
AVSel
Глобальный модератор
 
Аватар для AVSel
 
Регистрация: 15.02.2010
Последняя активность: 26.05.2019 19:08
Адрес: Москва
Сообщений: 3138
Сказал(а) спасибо: 79
Поблагодарили 107 раз(а) в 76 сообщениях
По умолчанию

Цитата:
Использовать МК в преобразователях для ЛД я не хотел до последнего момента. Они слишком медленно реагируют на изменения напряжения питания. Без дополнительных примочек я получил выбросы в 300мА на токе в 0,5A, если резко поднять напряжение питания на 1V (правда средний ток при таких пульсациях был всего 250мА)! Дребезг не страшен, т.к. ОС не успевает перерегулировать, но если вы запитаете драйвер, подождёте пока он вырулит нужный ток и резко поднимите напряжение - получите небольшой выброс, где-то в 50...100мА (если верить осциллографу).
Вот это меня и смущает. Если светодиод кратковременные 2-х и более кратные перегрузки переживает легко, то ЛД настанет каюк.
AVSel вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 17:33   8
Hobbi TV
Старший модератор
 
Аватар для Hobbi TV
 
Регистрация: 14.02.2010
Последняя активность: 18.11.2015 19:18
Адрес: Санкт-Петербург
Сообщений: 13534
Сказал(а) спасибо: 6
Поблагодарили 35 раз(а) в 30 сообщениях
По умолчанию

Цитата:
Посмотреть сообщение Сообщение от nevil :
с лпф будут покупать дрова?
Будут, только для этого еще кучу всего надо сделать...

Добавлено через 1 минуту
Цитата:
Посмотреть сообщение Сообщение от Vik :
Я досихпор не понял что произошло с моим
Так у тебя был китайский драйвер, работу которого ты не проверил...
Hobbi TV вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 18:00   9
INFERION
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию

Да возможно что и 12х такие же проблемные как 6х...
Цитата:
Посмотреть сообщение Сообщение от AVSel :
Вот это меня и смущает. Если светодиод кратковременные 2-х и более кратные перегрузки переживает легко, то ЛД настанет каюк.
Я пока не знаю как это устранить тут. АЦП даёт показания намного быстрее, чем выравнивается тяга. Я пока не придумал эффективный алгоритм вычисления точной поправки, для этого надо как-то узнавать характер нагрузки (его ВАХ), и считать прибавку мощности. Но ведь надо ещё знать как влияет длительность импульса на ток и т.п... Пока что я симулировал обычную ОС с тремя интеграторами ошибки. Просто и стабильно, но медленно. Для ускорения реакции стоят триггеры, они уже реагируют как только АЦП даст результат. Но сам АЦП по-прежнему остаётся очень медленным. Можно отключить всю мишуру и мерить только ток, это даст прибавку в скорости в 4 раза, но драйвер останется без защит...
Как вариант - найти более подходящие для этих задач МК. Кстати, заставить работать на 500кГц реально даже 13-ю тиньку, с падением на сенсоре где-то в 0,3V. Должно дать приемлемый результат...

Цитата:
 Сообщение от Ryazanec :
А я так в индикаторе и мерил, так как в момент включения приходится выбрасывать несколько выборок. Для индикатора без разницы - там от этой тормзнутости не сгорит ничего (да и погрешность не так страшна), а в драйвере только внешний делитель - нужно быстродействие.
А зачем так много выкидывать? Одного семпла разве недостаточно? А дальше просто сглаживать...
INFERION вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 18:09   10
AVSel
Глобальный модератор
 
Аватар для AVSel
 
Регистрация: 15.02.2010
Последняя активность: 26.05.2019 19:08
Адрес: Москва
Сообщений: 3138
Сказал(а) спасибо: 79
Поблагодарили 107 раз(а) в 76 сообщениях
По умолчанию

Цитата:
Посмотреть сообщение Сообщение от INFERION :
А зачем так много выкидывать? Одного семпла разве недостаточно? А дальше просто сглаживать...
Иногда почему-то не хватает, при смене источника опорного, значения меняются очень плавно. Хорошо помогает пауза на 200мкс, после переключения, подбирал правда эксперементально.
AVSel вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 21:45   11
Ryazanec
Переводчик
 
Регистрация: 04.05.2010
Последняя активность: 13.03.2019 20:23
Адрес: Рязань
Сообщений: 2389
Сказал(а) спасибо: 6
Поблагодарили 7 раз(а) в 6 сообщениях
По умолчанию

Наткнулся на одном блоге человек писал что он выбрасывал до 8 выборок при таком способе измерения, когда просыпается схема - то не сразу срабатывает и даёт точный результат.
Ryazanec вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 22:08   12
INFERION
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию

Ну, у меня повер-даун тут не юзается, да и переключение ИОН в данном случае исключено. Но дифференциальному усилителю наверняка требуется время, приходится пропускать семпл. Я в даташите не нашел нормального описания этого усилителя. Как он там подключен, какие у него параметры и т.п...
INFERION вне форума   Ответить с цитированием Вверх
Старый 04.04.2011, 22:18   13
AVSel
Глобальный модератор
 
Аватар для AVSel
 
Регистрация: 15.02.2010
Последняя активность: 26.05.2019 19:08
Адрес: Москва
Сообщений: 3138
Сказал(а) спасибо: 79
Поблагодарили 107 раз(а) в 76 сообщениях
По умолчанию

Цитата:
Посмотреть сообщение Сообщение от INFERION :
Но дифференциальному усилителю наверняка требуется время, приходится пропускать семпл. Я в даташите не нашел нормального описания этого усилителя. Как он там подключен, какие у него параметры и т.п...
Полоса 4КГц. Дальше считаете, сколько у вас выборок в секунду, и соответственно, сколько выборок надо выбросить. А вот источник опорного ведет себя странно, похоже кроме отключаемого внешнего конденсатора, есть еще какой-то внутренний.
AVSel вне форума   Ответить с цитированием Вверх
Старый 24.04.2011, 22:49   14
drakon
Лазеростроитель
 
Аватар для drakon
 
Регистрация: 01.12.2010
Последняя активность: 30.06.2013 00:20
Адрес: Украина, Харьков
Сообщений: 49
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
По умолчанию

если поднять частоту, можно его разогнать до 1А для синего?
drakon вне форума   Ответить с цитированием Вверх
Старый 24.04.2011, 23:20   15
INFERION
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию

Частоту необязательно поднимать. А максимальный ток ограничен тут в основном дросселем. Сейчас там дроссель на 1,3A. По-идее средний ток где-то в 2...3 раза ниже за реактивный, в зависимости от разницы напряжений и запаса по индуктивности. Увеличение частоты только увеличивает запас по индуктивности, уменьшает уровень пульсаций и т.п. В общем потребуется дроссель ампера на 3, два ключа в параллель, и индуктивность его можно уменьшить раза в 2 (в 4, если поднять частоту)...
Для синего можно и по-серьёзнее что-нибудь собрать...
INFERION вне форума   Ответить с цитированием Вверх
Старый 08.04.2013, 07:46   16
INFERION
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию

Т.к. схема из 1-го поста была заброшена в силу ряда причин - под 3.0 версией сейчас планируется вот это:
Нажмите на изображение для увеличения
Название: P4084445.JPG
Просмотров: 664
Размер:	206.1 Кб
ID:	9844
Вернее это не совсем 3.0. Это её специальная версия, исходники которой будут доступны. Отличается отсутствием подстроечника (вместо него узел, двигающий оптику) и наличием цанг для крепления к выводам ЛД (на фото они не впаяны, т.к. всё ещё жду их от SviMik'а). Размеры 10х2,5мм. Вот схема спец. версии:
Нажмите на изображение для увеличения
Название: Indigo 3.0s.png
Просмотров: 844
Размер:	77.5 Кб
ID:	9845
По-сути то же что и 4.0, только слабее и урезаннее. 3.0 от 3.0s отличается только тем, что нет куска с двумя TS5A3159, вместо резистора на PB0 сидит подстроечник, ползунок которого подключен к PB2. Прошивку к 3.0 я выкладывать не буду, но драйвер можно будет купить в магазине. 3.0s планировался для своих указок с уникальными коллиматорами, к нему я исходники прятать не планирую, всё равно он слишком специфичен, а его куски кода уже находятся в общем доступе (демка 4.0).
Эта платка насаживается до упора на выводы ЛД и распаивается. При этом МК, полевик и преобразователь лучше мазнуть термопастой для хорошего теплового контакта. Это позволит контролировать температуру ЛД и чуть повысит КПД.

[Исправлено: INFERION, 08.04.2013 в 08:02].
INFERION вне форума   Ответить с цитированием Вверх
Старый 08.04.2013, 13:17   17
Российская Федерация
Модератор
 
Аватар для Российская Федерация
 
Регистрация: 15.02.2010
Последняя активность: 20.06.2019 02:21
Адрес: город-герой Москва
Сообщений: 2308
Сказал(а) спасибо: 11
Поблагодарили 28 раз(а) в 18 сообщениях
По умолчанию

Я так понял, речь идёт об электро-приводе для оптики? Можно поподробнее об этом?))
Российская Федерация вне форума   Ответить с цитированием Вверх
Старый 08.04.2013, 20:40   18
INFERION
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию

Нажмите на изображение для увеличения
Название: коллиматор.png
Просмотров: 639
Размер:	164.8 Кб
ID:	9847
Идея в том, чтоб с минимальными усилиями избавится от необходимости ручной фокусировки, когда хочется повыжигать или посветить вдаль. Плавно фокус не порегулируешь, зато можно всё герметично закрыть и не боятся грязи. К тому же конструкция помещается в мелкие фонарики, на место AixiZ. Переключение фокуса происходит при переключении режимов задней кнопкой. Т.е. есть режимы с фокусом в бесконечность, а есть режим для выжигания, с фокусом около 10см. и макс. током.
Принцип работы - на дюралевом каркасе намотана катушка, в самом каркасе свободно ходит стальная гильза с вкрученной в неё акриловой оптикой, а по-бокам каркаса находится два неодимовых магнита. Стальная гильза будет намагничиватся катушкой и "прилипать" к соответствующему магниту. Короткий импульс нужной полярности и фокус переключен. Первый фокус настраивается обычным образом, другой задан конструктивно (ходом гильзы) и может в небольших пределах регулироваться стачиванием гильзы/каркаса...

Токарных работ мало, магниты доступны, метчики есть. Вот только хз как стекло вырезать аккуратно...
ЛД прижимается диском, который прикручивается к каркасу тремя саморезами с кареток (они мелкие, под них отверстие требуется всего в миллиметр).
INFERION вне форума   Ответить с цитированием Вверх
Старый 08.04.2013, 21:16   19
Российская Федерация
Модератор
 
Аватар для Российская Федерация
 
Регистрация: 15.02.2010
Последняя активность: 20.06.2019 02:21
Адрес: город-герой Москва
Сообщений: 2308
Сказал(а) спасибо: 11
Поблагодарили 28 раз(а) в 18 сообщениях
По умолчанию

Так это же фактически линейный двигатель, как в динамике, только с фиксацией по краям магнитами! Прикольно!
Российская Федерация вне форума   Ответить с цитированием Вверх
Старый 08.04.2013, 22:19   20
INFERION
Старший модератор
 
Аватар для INFERION
 
Регистрация: 15.02.2010
Адрес: Украина, Полтава
Сообщений: 1498
Сказал(а) спасибо: 0
Поблагодарили 2 раз(а) в 2 сообщениях
По умолчанию

Фактически да, только без ОС произвольно его не выставишь...

UPD:
Получил платы под 3.0 версию с подстроечником. Через пару дней спаяю кучку драйверов, с остальными вопросами к Диме . Кто живёт на Украине и заказал драйвер в магазине - вышлю напрямую. Возможно сможем месяц сэкономить, если вышлю напрямую в Россию, но тогда доставка двойная (если с магазина заказывается ещё что-то, кроме драйвера), т.к. со своего кармана я платить пока не готов .

[Исправлено: INFERION, 14.05.2013 в 19:46].
INFERION вне форума   Ответить с цитированием Вверх
Ответ


Здесь присутствуют: 1 (пользователей: 0 , гостей: 1)
 
Опции темы

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.


Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Индикатор заряда батареи на Attiny25 (Светофор) Ryazanec Разное 204 01.12.2015 12:21
Indigo 4.0 INFERION Драйверы для Синих ЛД 26 14.02.2014 22:06
USB зарядка для Li-ion на ATtiny25 INFERION Зарядные устройства 52 23.01.2013 19:35
Драйвер Indigo v2.0 INFERION Драйверы для Фиолетовых ЛД 61 10.01.2012 16:50
Indigo PE Hobbi TV Заявки на исследование 8 17.11.2011 14:47


Текущее время: 09:11. Часовой пояс GMT +4.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2019, vBulletin Solutions, Inc. Перевод: zCarot
Template-Modifications by TMS

Copyright ©2010 - 2015, Hobbi.TV & FONAREVKA.RU.

Если Вы не являетесь правообладателем того или иного контента размещенного на форуме (фото/видео/текст),
то при любом использовании материалов форума необходимо получить письменное разрешение
на использование того или иного материала у администрации форума.

При использовании материалов форума ссылка на Lasers.fonarevka.ru обязательна.

Украинский портАл CATALOG.METKA.RU
Каталог webplus.info Каталог сайтов Zabor.com